Tutorial CLEO Script BAB 1 Perkenalan

Tutorial CLEO Script BAB 1 Perkenalan - Sebelum memulai, sebaiknya anda mendownload tools yang ingin digunakan yaitu Sanny Builder, Silahkan anda Download & Install, klik disini.

Sekarang kita memulai mengedit Script, dan kali ini kita akan menggunakan MOD Spawn Pengamen Jalanan sebagai contoh script yang akan di edit. Berikut Script Tersebut :

$CLEO .cs}

thread "NGAMEN"

:NGAMEN_10
wait 10
if and
   Player.Defined($PLAYER_CHAR)
0ADC:   test_cheat "NGAMEN"
jf @NGAMEN_10
Model.Load(36)
Model.Load(98)
Model.Load(371)
Model.Load(579)
04ED: load_animation "DANCING"
038B: load_requested_models
jump @NGAMEN_78

:NGAMEN_78
wait 0
if and
   Model.Available(36)
   Model.Available(98)
   Model.Available(371)
   Model.Available(579)
04EE:   animation "DANCING" loaded
jf @NGAMEN_78
jump @NGAMEN_129

:NGAMEN_129
0ACA: show_text_box "PENGAMEN MUNCUL"
04C4: store_coords_to $4 $5 $6 from_actor $PLAYER_ACTOR with_offset 0.0 25.0 0.0
02C1: store_to $7 $8 $9 car_path_coords_closest_to $4 $5 $6
0395: clear_area 1 at $7 $8 $9 radius 8.0
$8 -= 5.0
$10 = Actor.Create(Mission1, 36, $7, $8, $9)
wait 0
$7 += 1.1
$12 = Actor.Create(Mission1, 98, $7, $8, $9)
wait 0
$8 += 2.5
$13 = Car.Create(579, $7, $8, $9)
Car.Angle($13) = 90.0
Actor.Health($10) = 100000
Actor.Health($12) = 100000
0446: set_actor $10 dismemberment_possible 0
0446: set_actor $12 dismemberment_possible 0
$23 = Object.Create(3027, 0.0, 0.0, 0.0)
070A: AS_actor $10 attach_to_object $23 offset -0.1 0.2 0.0 on_bone 1 16 perform_animation "NULL" IFP_file "NULL" time -1
wait 10
0812: AS_actor $10 perform_animation "CAR_HOOKERTALK" IFP "PED" framedelta 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1 // versionB
0812: AS_actor $12 perform_animation "DANCE_LOOP" IFP "DANCING" framedelta 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1 // versionB
jump @NGAMEN_507

:NGAMEN_507
wait 100
if and
   Player.Defined($PLAYER_CHAR)
00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere $7 $8 $9 radius 20.0 20.0 20.0
jf @NGAMEN_606
0@ = Audiostream.Load("CLEO\NAUFALIRFAN\NGAMEN.MP3")
Audiostream.PerformAction(0@, PLAY)
jump @NGAMEN_781

:NGAMEN_606
wait 0
if or
80FE:   not actor $PLAYER_ACTOR sphere 0 in_sphere $7 $8 $9 radius 90.0 90.0 90.0
0ADC:   test_cheat "NGAMEN"
jf @NGAMEN_507
wait 0
Actor.DestroyWithFade($10)
Actor.DestroyWithFade($12)
04EF: release_animation "DANCING"
Car.Destroy($13)
wait 1000
0ACA: show_text_box "PENGAMEN HILANG"
jump @NGAMEN_10

:NGAMEN_723
wait 0
if
80FE:   not actor $PLAYER_ACTOR sphere 0 in_sphere $7 $8 $9 radius 30.0 30.0 30.0
jf @NGAMEN_781
Audiostream.Release(0@)
jump @NGAMEN_606

:NGAMEN_781
wait 0
if or
80FE:   not actor $PLAYER_ACTOR sphere 0 in_sphere $7 $8 $9 radius 90.0 90.0 90.0
0ADC:   test_cheat "NGAMEN"
jf @NGAMEN_723
Actor.DestroyWithFade($12)
Actor.DestroyWithFade($10)
04EF: release_animation "DANCING"
Car.Destroy($13)
wait 1000
0ACA: show_text_box "PENGAMEN HILANG"
jump @NGAMEN_10

Konsep Dasar

Langkah pertama silahkan buka program Sanny Builder, kemudian pilih New Script untuk membuat Script.dibawah ini cara dan contoh membuat script dengan gambar beserta keterangannya:

1. Nomor Baris (Ini akan muncul otomatis untuk tiap baris)
2. Nama Bagian (Diawali dengan tanda ":" kemudian diberi nama terserah anda)
3. Kondisi, Jika dan
   Ini untuk mengawali no.6 (jf) baris diantara if & jf adalah kondisi, if diikuti 'and' jika kondisi lebih dari 1 dan harus semua 'true' untuk melewati 'jf', bisa juga 'if or' maka hanya butuh salah satu kondisi 'true' untuk melewati 'jf'
4. Global Function (Ada 11 Global function, salah satunya Model. dengan ini tidak perlu menulis Opcode, ini untuk fungsi umum)
5. Jump (Lompat)
   Perintah untuk melompat ke Bagian tertentu, nama bagian diawali @
6. Lompat Jika Salah
   jika kondisi diatasnya salah maka akan melompat ke bagian tertentu
   jika benar maka ini akan diabaikan, dan akan melanjutkan membaca kebawah
7. Opcode
   Kode unik untuk perintah, untuk list dan fungsi nya bisa dilihat disini
8. $Variabel
   Untuk menyimpan bilangan dalam symbol, dapat digunakan di perintah lain, vaule dapat di ubah sesuai perintah
9. Global Object
   Sebenarnya object di GTA digambarkan dengan nomor, dinamakan Object ID, tetapi dengan Global Object ini memudahkan untuk menulis Object, object yang umum bisa ditulis dengan #Nama

Script akan dibaca dari atas kebawah dalam waktu yang sangat singkat, seluruh script akan dibaca hampir bersamaan, jadi komputer kalian membaca baris demi baris urut dari atas tetapi sangat cepat, 'if' dan 'wait' dan 'jump' megatur pembacaan seperti gambar ini, wait untuk berhenti selama beberapa milisecond, jump untuk melompat, if untuk mengatur lompatan.

Contoh Pembacaan

:NGAMEN_1
wait 1
if and
 Player.Defined($PLAYER_CHAR)
0ADC:   test_cheat "NGAMEN"
jf @NGAMEN_1
Model.Load(36)
Model.Load(98)
Model.Load(371)
Model.Load(579)
04ED: load_animation "DANCING"
038B: load_requested_models
jump @NGAMEN_3

Dibaca :
Jika Player terdefinisi dan ketik cheat 'NGAMEN' maka load model yang sudah ditentukan dan anim 'DANCING' lalu lompat ke NGAMEN_3 jika tidak maka lompat ke NGAMEN_1

:NGAMEN_507
wait 100
if and
   Player.Defined($PLAYER_CHAR)
00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere $7 $8 $9 radius 20.0 20.0 20.0
jf @NGAMEN_606
0@ = Audiostream.Load("CLEO\NAUFALIRFAN\NGAMEN.MP3")
Audiostream.PerformAction(0@, PLAY)
jump @NGAMEN_781

Dibaca :

Jika Player terdefinisi dan berada disekitar titik dengan koordinat $7 $8 $9 dengan jarak kurang dari 20 meter maka load Audio NGAMEN.MP3 dan Mainkan audio itu lalu lompat ke NGAMEN_781 jika tidak maka lompat ke NGAMEN_606.

Gambaran Umum Script

Demikian Tutorial CLEO Script BAB 1 Perkenalan yang lengkap dengan gambarnya sehingga mempermudah anda dalam membuat CLEO MOD.Semoga bisa membantu.